Harjoitus 2 -- Ratkaisut

1 Listat

a Table-komento

Huom. (*-merkki aloittaa kommentin ja *)-merkki päättää sen.

Table[(x^2),{x,1 (*1. x:n arvo*),100 (*viimeinen x:n arvo*),1 (*askelpituus*)}]

tai lyhyemmin (oletusarvoisesti ensimmäinen arvo ja askelpituus ovat 1):

Table[(x^2),{x,100}]

Summa lasketaan Sum-funktiolla, Length antaa listan alkioiden lukumäärän.

Sum[%[[i]],{i,Length[%]}]

Toinen, kätevä tapa laskea taulukon alkioiden summa on Total-funktiolla, argumentiksi annetaan summattava lista.

Total[%%]

b Pistetulo

Vektoreita ja matriiseja kuvataan Mathematicassa listoilla:

a={2,-3};b={-1,1};

Vektorien välinen kulma on cos α=(((OverBar[a])·(OverBar[b]))/(|(OverBar[a])| |(OverBar[b])|)). Pistetulo lasketaan Dot-funktiolla (tai kirjoittamalla piste vektorien väliin) ja vektorin pituus Norm-funktiolla. α-kirjain kirjoitetaan esc-a-esc.

α=ArcCos[((a.b)/(Norm[a]Norm[b]))]//N

Yo. kulma on radiaaneja. Sama asteina on

α/Degree

c Ristitulo

Kahden vektorin ristitulo on kohtisuorassa kumpaakin vektoria vastaan, ts. kohtisuorassa niiden määrämää tasoa vastaan. Huom. ristitulo on määritelty vaan kolmiulotteisille vektoreille. Ristitulovektorista saa yksikkövektorin jakamalla pituudella.

a={2,-1,3};b={0,-1,-1};
n=Cross[a,b];
n=n/Norm[n]

d Matriisit

Matriisi määritellään Mathematicassa listana, jonka alkiot ovat listoja. Nämä osalistat vastaavat matriisin vaakarivejä. Eigenvectors-komento antaa listan, jonka alkiot ovat matriisin ominaisvektoreita.

m={{2,-1},{3,1}};
mi=Inverse[m];
evec=Eigenvectors[m];
eval=Eigenvalues[m];
x1=evec[[1]];
x2=evec[[2]];
λ1=eval[[1]];
λ2=eval[[2]];
Print["M = ",MatrixForm[m]]
Print["det M = ",Det[m]]
Print["M:n käänteismatriisi: (M^(-1)) = ",MatrixForm[mi] ]
Print["M:n ominaisvektorit: (Subscript[X, 1]) = ",MatrixForm[x1]," ja (Subscript[X, 2]) = ",MatrixForm[x2]]
Print["M:n ominaisarvot: (Subscript[λ, 1]) = ",λ1," ja (Subscript[λ, 2]) = ",λ2]

Tarkistetaan tulokset. Nyt täytyisi olla M (M^(-1))=(M^(-1))M=I=(({{1, 0}, {0, 1}})), ja M (Subscript[X, i])=(Subscript[λ, i])(Subscript[X, i]), i=1,2.

m.mi//MatrixForm
mi.m//MatrixForm
((m.x1)/(λ1))//MatrixForm
((m.x2)/(λ2))//MatrixForm

Nyt ominaisvektorit on vain esitetty eri muodossa. FullSimplify paljastaa yhtäsuuruuden (Voit kokeilla myös Simplify-funktiota. Se ei osaa sieventää kompleksilukuja):

Print[MatrixForm[FullSimplify[x1]]," = ",MatrixForm[FullSimplify[((m.x1)/(λ1))]]]
Print[MatrixForm[FullSimplify[x2]]," = ",MatrixForm[FullSimplify[((m.x2)/(λ2))]]]

e Indeksöinti

Muuttujien indeksöinti on kätevä tapa käsitellä useampaa kuin yhtä muuttujaa jonkin kollektiivisen nimen ja numeron avulla. Tämä eroaa listoista siinä mielessä, että "listan" kokoa ei tarvitse määritellä -- indeksöinti vastaa ikään kuin tietokannan luomista. Huom. seuraava komento asettaa A:n arvoksi MatrixForm-muodossa olevan olion. Sen jälkeen A:ta käsiteltäessä olisi aina kirjoitettava A[[1]] jos haluttaisiin viitata koko listaan. FullForm-komento näyttää kaikki olion rakenneosat (sitä ei yleensä tarvitse missään). Esim. aaltosulkeilla muodostettu lista on Mathematican sisällä muodossa List[...].

A=Table[Random[],{3},{3}]//MatrixForm

FullForm[A]
2A (*Mathematica ei osaa laskea kertolaskua*)
A[[1]]

Kannattaa siis erottaa MatrixForm-komento matriisin luomiskäskystä.

A=Table[Random[],{3},{3}];
MatrixForm[A]

Eigenvectors-funktio antaa taulukon, jonka alkiot ovat matriisin ominaisvektorit. Huomaa pistetuloista, että Eigenvectors-komento automaattisesti normittaa ominaisvektorit (pituus on 1).

a=.
evec=Eigenvectors[A];
a[1]=evec[[1]];
a[2]=evec[[2]];
a[3]=evec[[3]];
Table[a[i].a[j],{i,3},{j,3}]//MatrixForm

Indeksöinnin etuja on se, että ominaisvektorit voidaan merkitä vaikka ominaisarvojen avulla. Toisaalta tämä merkintä saattaa vaikeuttaa niihin viittaamista, ja ominaisvektorien oletusarvoinen järjestys on melko hyvä (suurinta ominaisarvoa vastaava vektori on ensimmäinen ja pienintä vastaava viimeinen). Toisaalta taas, jos ominaisarvoja on paljon (suuri matriisi) ja halutaan jotain tiettyä ominaisarvoa vastaava ominaisvektori, niin tällä merkinnällä on etunsa.

?a

Seuraavassa Do[lauseke,{i,imax}] suorittaa lausekkeen, joka riippuu i:stä, imax kertaa. Lisää tästä seuraavissa harjoituksissa. Huom. indeksöityä muuttujaa ei saa tyhjennettyä komennolla a=., vaan tarvitaan Remove-käsky.

Remove[a];
eval=Eigenvalues[A];
Do[a[eval[[i]]]=evec[[i]],{i,3}]

?a

Indeksöintiä tullaan käyttämään myöhemmin lisää.

2 Kuvaajien piirtäminen

a) Perus-plottaus

Plot[{Sin[x],Cos[2x]},{x,0,2π}]

b) Pisteiden plottaus

Prime[n] antaa n:nnen alkuluvun (ts. Prime[1]=2, Prime[2]=3, jne)

alkuluvut=Table[{n,Prime[n]},{n,20}]
ListPlot[%]

c Parametrinen käyrä

ParametricPlot-funktio sotkee jostain syystä kuvan mittasuhteet. Mittasuhteita voi säätää asetuksella AspectRatio. GoldenRatio on matemaattinen vakio, "kultaisen leikkauksen" suhdeluku.

x[t_]:=(t^3)+t-1;y[t_]:=Sin[1/((t^2)+1)];
ParametricPlot[{x[t],y[t]},{t,-2,2},AspectRatio->1/GoldenRatio]

d

Manipulate-komennolla mitä tahansa lausekkeita voidaan kätevästi muokata jonkin parametrin suhteen -- erinomainen työkalu havainnollistamiseen. Syntaksi on Manipulate[lauseke,{p,pmin,pmax}], missä lauseke riippuu parametrista p. Plot-komennon asetus PlotRange määrää y-akselin rajat.

a=.;x=.;
Manipulate[Plot[((Sin[a x])/x),{x,-2,2},PlotRange->{-2,10}],{a,1,10}]

Manipulate toimii minkä tahansa lausekkeiden kanssa. Esim.

Manipulate[x,{x,0,10}]

Manipulate[Sum[((x^i)/(i!)),{i,0,n}],{n,0,10}]

Myös useamman parametrin suhteen voidaan manipuloida.

Manipulate[Plot3D[Sin[a x]Cos[b y],{x,-π,π},{y,-π,π}],{a,0.5,2},{b,0.5,2}]

i=.;n=.;
Manipulate[ListPlot[Table[{i,Prime[i]},{i,1,n}]],{n,1,100}]

3 Tiedostonkäsittely

Tiedostoja luotaessa on hyvä tietää, mihin ne luodaan. Directory[] antaa senhetkisen työhakemiston. Jos haluat muuttaa oletusarvoa, käytä SetDirectory["hakemistopolku"]-funktiota.

Directory[]

Jos tiedostoon kirjoitetaan >>-komennolla, taulukot kirjoittuvat aaltosulkeineen päivineen, ts. tiedostoon tulee Mathematica-koodia. Tiedostoa, johon kirjoitetaan, ei tarvitse erikseen luoda.

alkuluvut>>harj2t3a.m

Tiedoston sisältämä Mathematica-koodi ajetaan <<-komennolla. Tiedoston viimeisen käskyn tulos tulostetaan näytölle, ja sen voi vaikka sijoittaa muuttujaan. Tämä mahdollistaa funktioiden kirjoittamisen tiedostoon.

alkuluvut=.
alkuluvut=<<harj2t3a.m

Komennolla <<< lisätään jo olemassa olevan tiedoston loppuun (<< tyhjentäisi tiedoston).

alkuluvut2=Table[{n,Prime[n]},{n,21,40}];
alkuluvut2>>>harj2t3a.m

Nyt jos yllä luodun tiedoston sisältö ajetaan Mathematicassa, se tulostaa vain viimeksi lisätyn taulukon sisällön.

<<harj2t3a.m

Jos taulukko halutaan kirjoittaa tiedostoon nättiin taulukkomuotoon, voidaan käyttää esim. Export-funktiota (argumentti "Table" kertoo, että taulukko kirjoitetaan tiedostoon kaksisarakkeisessa muodossa:

Export["harj2t3a.txt",alkuluvut,"Table"]

Tällöin tosin tiedoston loppuun lisääminen ei onnistu. Listat voi vaikka yhdistää ennen tiedostoon kirjoittamista, Join-funktiolla:

Join[alkuluvut,alkuluvut2]

Export["harj2t3a.txt",%,"Table"]

Kahteen sarakkeeseen kirjoitettuja taulukoita luetaan tiedostoista Import-komennolla. Se siis lukee raakaa dataa ja muuttaa sen Mathematicassa käytettävään muotoon.

Import["harj2t3a.txt","Table"]

b

Tämä tehtävää varten ladataan Units-paketista yksiköiden määrittelyt. Kun nämä käskyt kirjoitetaan erilliseen tiedostoon (ks. harj2t3b.m), yläindeksejä sun muita ei voi käyttää.

<<Units`

Nopeusfunktiossa t on aika sekunteina, joten aina kun t esiintyy kaavassa, lisätään perään yksikkö Second.

a=0.1(Second^(-1));b=(10^(-4))(Second^(-2));t=.;
v1[t_]:={2,-1,(1/2)}(Meter/Second);
v2[t_]:={2a t Second,-1,((b (t^2)(Second^2))/2)} (Meter/Second);

Kappaleen paikka ajan funktiona on (OverBar[r])(t)=(OverBar[r])(0)+(∫_0^t)(OverBar[v])(t')dt', tai vakionopeuden tapauksessa (OverBar[r])(t)=(OverBar[r])(0)+v t. Integraali lasketaan Mathematicassa komennolla Integrate[f,{x,xmin,xmax}], missä f on jokin x:n funktio, ja integroimisrajat ovat xmin:stä xmax:iin. Määrittelen seuraavassa kappaleen paikan t:n funktioksi, joten integroimismuuttujalle on annettava jokin toinen nimi, esim. 'ti'.

r0={-6,0,2}Meter;
r1[t_]:=r0+v1[t]*t Second
r2[t_]:=r0+Integrate[v2[ti],{ti,0,t}]Second

Funktioiden r1 ja r2 lausekkeilla pitäisi olla yksikkönä Meter.

r1[t]
r2[t]

Integroimis- ja piirtämisrajojen (PlotRange) hakeminen tapahtuu yrityksen ja erehdyksen kautta. Ei tästä lentoradasta kovin hienoa kuvaa saa. Huom. r[t]:llä on yksikkö Meter. Piirtofunktio ei osaa käsitellä sitä, joten se pitää jakaa pois.

ParametricPlot3D[r1[t]/Meter,{t,0,20},PlotRange->{{-20,20},{-20,20},{-20,20}}]

ParametricPlot3D[r2[t]/Meter,{t,0,20},PlotRange->{{-20,20},{-20,20},{-20,20}}]

Samat käskyt, ei-vakioisen nopeuden tapauksessa, on kirjoitettu tiedostoon harj2t3b.m. Tallenna se Directory[]-funktion näyttämään hakemistoon ja aja se.

<<harj2t3b.m

c)

Käytetään taas indeksöityjä muuttujia.

a=.
A={{2,2,-1},{-1,-1,1},{0,1,2}};
Do[a[i]=Eigenvectors[A][[i]],{i,3}]

Seuraavassa r:n on oltava vektori (ts. jokin olio, jolle pistetulo a[i]:n kanssa on määritelty).

f[r_]:=Sum[((((a[i].r))^2)/2),{i,3}]

f[{1,2,-1}]

Voitaisiin myös määritellä

g[x_,y_,z_]:=Sum[((((a[i].{x,y,z}))^2)/2),{i,3}]

g[1,2,-1]

Huomaa ero funktioiden f ja g käytössä! f ottaa vain yhden argumentin, joka on vektori (3-alkioinen lista). g ottaa kolme argumenttia. Piirretään f:n kuvaaja:

Manipulate[Plot3D[f[{x,y,z}],{x,-1,1},{y,-1,1},PlotRange->{0,50}],{z,-3,3}]